home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Tech Arsenal 1
/
Tech Arsenal (Arsenal Computer).ISO
/
tek-13
/
amac44c.zip
/
RFR001.QM
< prev
next >
Wrap
Text File
|
1992-05-27
|
5KB
|
130 lines
* rfr001.qm
* Macros To Single/Double/Triple Space Files
* Written By Tom Hogshead
* [ See RFRMxx.QM For Use ]
* 5/30/92
* Key Subfile Description
* ===== =============== ====================================================
* @1 Single Space File ( )
* @2 Double Space File
* @3 Triple Space File
* @4 Make All Blank Lines In File Single Space,
* Condenses for better readability
*
* {e:\up\RFRM*}--Return To RFRMxx.QM
*
*-- eoi
*
* ------------------------------------------------------------------
* @(1) Single Space File, Requires Qedit v2.15
* ------------------------------------------------------------------
@1 macrobegin
Begfile
SetScreenOff * Remove if not Qedit v2.15
CHK4BLANK:
Endline Begline * Test if line has text
Jtrue NOTBLANK:
Delline
Jtrue CHK4BLANK:
NOTBLANK:
Endpara Cursordown
Jtrue CHK4BLANK:
Begfile
*
* 20 bytes Wed 02-20-1991 16:48:58 (TH @f7)
* 37 bytes Tue 07-02-1991 16:20:47 (TH @1, added windows)
* 21 bytes Tue 10-08-1991 12:22:20 (TH @1, removed windows, added v2.15)
*
*----------------------------------------------------------------------
* @(2) Double Space File, Requires QEdit v2.15
*----------------------------------------------------------------------
@2 Macrobegin
Begfile
SetScreenOff * Remove if not Qedit v2.15
START:
Endline Begline * Test if line has text
Jfalse DEL_BLANK:
INS_BLANK: Cursordown
Jfalse END: * If at eof, END macro
Endline Begline * Test if line has text
Jfalse NEXT_LINE:
Insertline Cursordown
Jump INS_BLANK:
NEXT_LINE: Cursordown
Jump START:
DEL_BLANK:
Cursordown * Test if eof
Jfalse END: * If at eof, END macro
Cursorup DelLine * Delete second blank line
Jump START:
END: Begfile
*
* 38 bytes Fri 02-22-1991 13:22:05
* 55 bytes Sun 07-14-1991 17:45:16 (TH @2, added windows)
* 39 bytes Tue 10-08-1991 12:23:36 (TH @2, removed windows, added v2.15)
*
*-----------------------------------------------------------------------
* @(3) Triple Space File, Requires QEdit v2.15
*-----------------------------------------------------------------------
@3 Macrobegin
Begfile
SetScreenOff * Remove if not Qedit v2.15
INITIAL:
Endline Begline * Test if line 1 has text
Jtrue START:
Delline
Jump INITIAL:
START:
Endline Begline * Test if line has text
Jfalse DEL_BLANK:
INS_BLANK: Cursordown
Jfalse END: * If at eof, END macro
Endline Begline * Test if next line has text
Jfalse DEL_BLANK:
Insertline Addline Cursordown
Jump INS_BLANK:
DEL_BLANK: Cursordown
Jfalse END: * If at eof, END macro
Endline Begline * Test if line has text
Jfalse CONTINUE:
Insertline Cursordown
Jump INS_BLANK:
CONTINUE: Cursordown
NEXT: Endline Begline * Test if line has text
Jtrue INS_BLANK:
Delline
Jtrue NEXT: * If at eof, can't delete more
* than 1 blank line, then END
END: Begfile
*
* 62 bytes Sun 02-24-1991 13:33:59
* 79 bytes Sun 07-14-1991 17:48:05 (TH @3, added windows)
* 60 bytes Tue 10-08-1991 17:04:33 (TH @3, removed windows, added v2.15)
*
* ---------------------------------------------------------------------
* @(4) Make All Blank Lines In File Single Space
* ---------------------------------------------------------------------
* This macro is handy for condensing files, so that there are
* only single blank lines between text for better screen readability.
* This macro requires QEdit v2.15.
@4 Macrobegin
Begfile
SetScreenOff * Remove if not Qedit v2.15
CHK4BLANK:
Endline Begline * Test if line has text
Jtrue NOTBLANK:
Delline
Jtrue CHK4BLANK:
NOTBLANK:
Endpara Cursordown Cursordown
Jtrue CHK4BLANK: Begfile
*
* 21 bytes Wed 02-20-1991 16:46:39
* 38 bytes Sun 07-14-1991 17:36:39 (TH @4, added windows)
* 22 bytes Tue 10-08-1991 12:10:57 (TH @4. removed windows, added v2.15)